nix-dotfiles-v2/flake.nix

{
  description = "NixOS configuration for legolas (laptop)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    unstable.url = "github:NixOS/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    noctalia = {
      url = "github:noctalia-dev/noctalia-shell";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-colors.url = "github:misterio77/nix-colors";
    stylix = {
      url = "github:nix-community/stylix/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.4.3";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nixos-hardware.url = "github:NixOS/nixos-hardware/master";

    nixvim = {
      url = "github:nix-community/nixvim/nixos-25.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    blog-generator.url = "github:adrlau/blog-generator";

    niri = {
      url = "github:sodiboo/niri-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };

  };

  outputs =
    {
      self,
      nixpkgs,
      unstable,
      home-manager,
      nix-colors,
      stylix,
      sops-nix,
      lanzaboote,
      nixos-hardware,
      blog-generator,
      niri,
      noctalia,
      nixvim,
      ...
    }@inputs:
    let
      system = "x86_64-linux";
    in
    {
      packages.${system} =
        let
          lib = nixpkgs.lib;
          pkgs = import nixpkgs {
            inherit system;
            overlays = [ self.overlays.custom ];
            config.allowUnfree = true;
          };
        in
        {
          inherit (pkgs.custom)
            qwen-asr
            llama-swap
            z-image-models
            whisper-models
            s2cpp
            s2-model
            vllm-omni
            llama-cpp-nightly
            llama-cpp-nightly-vulkan
            llama-cpp-nightly-sycl
            android-cli
            ;
        };

      overlays.custom = final: _prev: let
        unstable-pkgs = import inputs.unstable { inherit (final.stdenv.hostPlatform) system; };
      in {
        custom = {
          qwen-asr = final.callPackage ./packages/qwen-asr { };
          llama-swap = final.callPackage ./packages/llama-swap { buildGoModule = unstable-pkgs.buildGoModule; };
          z-image-models = final.callPackage ./packages/z-image-models { };
          whisper-models = final.callPackage ./packages/whisper-models { };
          s2cpp = final.callPackage ./packages/s2cpp { };
          s2-model = final.callPackage ./packages/s2-model { };
          vllm-omni = final.python3Packages.callPackage ./packages/vllm-omni { };
          llama-cpp-nightly = final.callPackage ./packages/llama-cpp-nightly { };
          llama-cpp-nightly-vulkan = final.callPackage ./packages/llama-cpp-nightly { vulkanSupport = true; };
          llama-cpp-nightly-sycl = final.callPackage ./packages/llama-cpp-nightly {
            syclSupport = true;
            mkl = final.mkl;
            oneDNN = final.oneDNN;
          };
          android-cli = final.callPackage ./packages/android-cli { };
        };
      };

      overlays.unstable = final: _prev: {
        unstable = import inputs.unstable {
          inherit (final.stdenv.hostPlatform) system;
          config = {
            allowUnfree = true;
            segger-jlink.acceptLicense = true;
          };
        };
      };

      # legolas
      nixosConfigurations.legolas = nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = { inherit inputs system; };
        modules = [
          ./hosts/legolas/configuration.nix

          home-manager.nixosModules.home-manager
          {
            home-manager.users.gunalx = import ./home/gunalx.nix;
            home-manager.backupFileExtension = "bac";
            home-manager.extraSpecialArgs = { inherit nix-colors inputs; };
            home-manager.sharedModules = [
              inputs.sops-nix.homeManagerModules.sops
              inputs.stylix.homeModules.stylix
              inputs.niri.homeModules.niri
              inputs.noctalia.homeModules.default
              inputs.nixvim.homeModules.nixvim
            ];
          }

          {
            nixpkgs.config.allowUnfree = true;
            nixpkgs.overlays = [
              self.overlays.custom
              self.overlays.unstable
              niri.overlays.niri
            ];
            home-manager.users.gunalx = {
              nixpkgs.config.allowUnfree = true;
              nixpkgs.overlays = [
                self.overlays.custom
                self.overlays.unstable
                niri.overlays.niri
              ];
            };
          }

          sops-nix.nixosModules.sops

          lanzaboote.nixosModules.lanzaboote

          nixos-hardware.nixosModules.dell-xps-13-9370

          #temporarily for testing run my blog on my laptop
          blog-generator.nixosModules.default

        ];
      };

      # aragon
      nixosConfigurations.aragon = nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = { inherit inputs system; };
        modules = [
          ./hosts/aragon/configuration.nix

          home-manager.nixosModules.home-manager
          {
            home-manager.users.gunalx = import ./home/gunalx.nix;
            home-manager.backupFileExtension = "bac";
            home-manager.extraSpecialArgs = { inherit nix-colors inputs; };
            home-manager.sharedModules = [
              inputs.sops-nix.homeManagerModules.sops
              inputs.stylix.homeModules.stylix
              inputs.niri.homeModules.niri
              inputs.noctalia.homeModules.default
              inputs.nixvim.homeModules.nixvim
            ];
          }

          {
            nixpkgs.config.allowUnfree = true;
            nixpkgs.overlays = [
              self.overlays.custom
              self.overlays.unstable
              niri.overlays.niri
            ];
            home-manager.users.gunalx = {
              nixpkgs.config.allowUnfree = true;
              nixpkgs.overlays = [
                self.overlays.custom
                self.overlays.unstable
                niri.overlays.niri
              ];
            };
          }

          sops-nix.nixosModules.sops

          lanzaboote.nixosModules.lanzaboote

          ];
      };

      # galadriel
      nixosConfigurations.galadriel = nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = { inherit inputs system; };
        modules = [
          {
            nixpkgs.config.allowUnfree = true;
            nixpkgs.overlays = [
              self.overlays.custom
              self.overlays.unstable
            ];
          }

          ./hosts/galadriel/configuration.nix

          sops-nix.nixosModules.sops

          lanzaboote.nixosModules.lanzaboote

        ];
      };

      # elros
      nixosConfigurations.elros = nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = { inherit inputs system; };
        modules = [
          {
            nixpkgs.config.allowUnfree = true;
            nixpkgs.overlays = [
              self.overlays.custom
              self.overlays.unstable
            ];
          }
          ./hosts/elros/configuration.nix
          sops-nix.nixosModules.sops
          lanzaboote.nixosModules.lanzaboote
        ];
      };

    };
}