Initial commit

flake.nix

@@ -0,0 +1,69 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+
+    rust-overlay.url = "github:oxalica/rust-overlay";
+    rust-overlay.inputs.nixpkgs.follows = "nixpkgs";
+  };
+
+  outputs = { self, nixpkgs, rust-overlay }:
+  let
+    inherit (nixpkgs) lib;
+
+    systems = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "armv7l-linux"
+    ];
+
+    forAllSystems = f: lib.genAttrs systems (system: let
+      pkgs = import nixpkgs {
+        inherit system;
+        overlays = [
+          (import rust-overlay)
+        ];
+      };
+
+      rust-bin = rust-overlay.lib.mkRustBin { } pkgs.buildPackages;
+      toolchain = rust-bin.stable.latest.default;
+    in f system pkgs toolchain);
+  in {
+    apps = forAllSystems (system: pkgs: _: {
+      default = self.apps.${system}.thumbctl;
+      thumbctl = let
+        package = self.packages.${system}.thumbctl;
+      in {
+        type = "app";
+        program = lib.getExe package;
+      };
+    });
+
+    devShells = forAllSystems (system: pkgs: toolchain: {
+      default = pkgs.mkShell {
+        nativeBuildInputs = [
+          toolchain
+          pkgs.pkg-config
+        ];
+
+        buildInputs = [
+          # pkgs.systemdLibs.dev
+          pkgs.dbus.dev
+        ];
+
+        RUST_SRC_PATH = "${toolchain}/lib/rustlib/src/rust/library";
+      };
+    });
+
+    overlays = {
+      default = self.overlays.thumbctl;
+      thumbctl = final: prev: {
+        inherit (self.packages.${prev.system}) thumbctl;
+      };
+    };
+
+    packages = forAllSystems (system: pkgs: _: {
+      default = self.packages.${system}.thumbctl;
+      thumbctl = pkgs.callPackage ./default.nix { };
+    });
+  };
+}