config/users/pbsds/home/profiles/gnome/default.nix

# Handwritten!
{ config, lib, pkgs,  ... }:

let
  gnomeExtensions = builtins.attrValues { inherit (pkgs.gnomeExtensions)
    #gnomeExtensions.big-avatar
    bluetooth-quick-connect
    gtile
    just-perfection
    keep-awake
    middle-click-to-close-in-overview
    vertical-workspaces
    #vertical-overview # RIP
    appindicator
    removable-drive-menu
    always-show-titles-in-overview
    vitals
    /* TODO:
    night-light-slider
    tray-icons-reloaded
    removable-drive-menu
    battery-indicator-upower
    workspace-indicator-2
    forge
    */
  ;};
in

{
  home.file.".local/opt/open-microsoft-url-files.py".source   = ../../files/opt/open-microsoft-url-files.py;
  home.file.".local/opt/python-interactive-imports.py".source = ../../files/opt/python-interactive-imports.py;
  home.file.".local/opt/sympy-interactive-imports.py".source  = ../../files/opt/sympy-interactive-imports.py;

  # qt theme
  qt.enable = true;
  qt.platformTheme = lib.mkMerge [
    (lib.mkIf (lib.versionAtLeast config.home.version.release "24.05") { name = "advaita"; })
    (lib.mkIf (lib.versionOlder config.home.version.release "24.05") "gnome")
  ];
  qt.style.name = "Colloid-dark";
  qt.style.package = pkgs.colloid-kde;

  imports = [
    ./dconf-gnome-bindings.nix
    ./dconf-gnome-extensions.nix
    ./dconf-gnome-theme.nix
  ];

  home.packages = [
    pkgs.gnome.gnome-tweaks
    pkgs.vimix-gtk-themes # shell theme
  ] ++ gnomeExtensions;

  dconf.settings = with lib.hm.gvariant; {
    # extensions:
    "org/gnome/shell" = {
      disable-user-extensions = false;
      enabled-extensions = lib.forEach gnomeExtensions (pkg: pkg.extensionUuid);
    };

    # wallpaper
    "org/gnome/desktop/background" = {
      color-shading-type = "solid";
      picture-options = "zoom";
      picture-uri = "file://${../../files/wallpaper.jpg}";
      picture-uri-dark = "file://${../../files/wallpaper.jpg}";
    };
    "org/gnome/desktop/screensaver" = {
      idle-activation-enabled = false;
      picture-uri = "file://${../../files/screensaver.jpg}";
    };

    # theme
    "org/gnome/desktop/interface" = {
      color-scheme = "prefer-dark";
      enable-hot-corners = false;
      clock-show-weekday = true;
    };
    #"org/gnome/desktop/wm/preferences" = {
    #  button-layout = ":minimize,close";
    #};

    # behaviour
    "org/gnome/desktop/peripherals/touchpad" = {
      disable-while-typing = false;
      natural-scroll = false;
      two-finger-scrolling-enabled = true;
    };
    "org/gnome/nautilus/preferences" = {
      confirm-trash = true;
      executable-text-activation = "display";
      show-create-link = true;
      sort-directories-first = true;
      #recursive-search = "never";
      show-image-thumbnails = "always";
      show-directory-item-counts = "always";
    };
    "org/gnome/nautilus/list-view" = {
      use-tree-view = true;
    };
    "org/gtk/gtk4/settings/file-chooser" = {
      sort-directories-first = true;
    };
    "org/gtk/settings/file-chooser" = {
      sort-directories-first = true;
    };

    "org/gnome/settings-daemon/plugins/color" = {
      night-light-enabled = true;
      night-light-schedule-automatic = false;
      night-light-schedule-from = 23.5;
      night-light-schedule-to = 5.0;
      night-light-temperature = mkUint32 4150;
    };

    #dump "org/gnome/settings-daemon/plugins/power"

    #"org/gnome/desktop/session" = {
    #  idle-delay = mkUint32 (5 * 60);
    #};
    "org/gnome/settings-daemon/plugins/power" = {
      sleep-inactive-ac-type = "nothing";
      sleep-inactive-battery-type = "suspend";
    };

  };
}