{
  description = "A flake for dwl";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
  };

  outputs =
    {
      self,
      nixpkgs,
    }:
    let
      system = "x86_64-linux";
      patches = [];
      pkgs = nixpkgs.legacyPackages.${system};
      nativeBuildInputs = with pkgs; [
        installShellFiles
        pkg-config
        wayland-scanner
      ];
      buildInputs = with pkgs; [
        libinput
        libxcb
        libxkbcommon
        pixman
        wayland
        wayland-protocols
        wlroots_0_19
      ];
      inherit (pkgs) lib;
    in
    {
      devShells.${system}.default =
        with pkgs;
        mkShell {
          inherit buildInputs nativeBuildInputs;
        };

      packages.${system} =
        let
          src = lib.fileset.toSource {
            root = ./.;
            fileset = lib.fileset.unions [
              ./Makefile
              ./client.h
              ./config.def.h
              ./config.mk
              ./dwl.c
              ./dwl.1
              ./dwl.desktop
              ./protocols
              ./util.c
              ./util.h
            ];
          };
        in
        {
          default = pkgs.callPackage ./package.nix { inherit src buildInputs nativeBuildInputs patches; };
        };

      overlays = {
        default = self.overlays.dwl;
        dwl = final: prev: {
          inherit (self.packages.${prev.stdenv.hostPlatform.system}) default;
        };
      };

      nixosModules = {
        default = self.nixosModules.dwl;
        dwl = ./module.nix;
      };
    };
}