{
  description = "A flake for running pokemon fangames, often via wine";

  inputs.erosanix.url = "github:emmanuelrosa/erosanix";
  inputs.erosanix.inputs.nixpkgs.follows = "nixpkgs";

  outputs = {
    self,
    nixpkgs,
    erosanix,
    ...
    } @ inputs:
  {

    packages.x86_64-linux = with nixpkgs.legacyPackages.x86_64-linux; rec {

      badown = callPackage ./pkgs/badown.nix {};
      mediafire-dl = python3Packages.callPackage ./pkgs/mediafire-dl.nix {};

      inherit (callPackage ./pkgs/fetchers.nix { inherit badown mediafire-dl; })
        fetchFromDrive
        fetchFromMega
        fetchFromMediafire;

      pokemon = let
        callPackage = newScope (erosanix.lib.x86_64-linux // {
          wine = wineWowPackages.full;
          wineArch = "win64";
          inherit
            fetchFromDrive
            fetchFromMega
            fetchFromMediafire;
        });
      in {

        # mkWindowsApp resources:
        # - https://github.com/emmanuelrosa/erosanix/tree/master/pkgs/mkwindowsapp
        # - https://github.com/emmanuelrosa/sumatrapdf-nix/blob/master/sumatrapdf.nix

        infinite-fusion = callPackage ./games/infinite-fusion.nix {
          legacy-version = false;
        };

        infinite-fusion-legacy = callPackage ./games/infinite-fusion.nix {
          legacy-version = true;
          wine = winePackages.full;
          wineArch = "win32";
        };

        project-untamed = callPackage ./games/project-untamed.nix { };

        uranium = callPackage ./games/uranium.nix { wine = winePackages.full; wineArch = "win32"; };

        clockwork = callPackage ./games/clockwork.nix { wine = winePackages.full; wineArch = "win32"; };

      };

    };

    # garbage-collect
    apps.x86_64-linux.gc = {
      type = "app";
      program = "${erosanix.packages.x86_64-linux.mkwindowsapp-tools}/bin/mkwindows-tools-gc";
    };

    lib.x86_64-linux = {
      inherit (self.packages.x86_64-linux)
        fetchFromDrive
        fetchFromMega
        fetchFromMediafire;
    };

  };
}