nixos-config/hosts/worf/home.nix

{ pkgs
, lib
, inputs
, config
, ...
}: {
  imports = [
    ./../../home/base.nix
    ./../../home/alacritty.nix
    ./programs/newsboat
  ];

  home.packages = with pkgs; [
    # prismlauncher
    borgbackup
    catimg
    cocoapods
    emacs-macport
    feishin
    gnutar
    iterm2
    nix-index
    nodejs
    spotify
    tldr
    unstable.aerc
    unstable.snicat
    w3m
    zellij

    (python311.withPackages (ps: with ps; [
      pwntools
      pycryptodome
      requests
    ]))
  ];

  programs.zsh = {
    shellAliases."rebuild" = "darwin-rebuild switch --flake /Users/felixalb/nix";
    prezto.pmodules = [ "ssh" ];
  };

  programs.neovim.plugins = with pkgs.vimPlugins; [
    coc-emmet
    copilot-vim
    emmet-vim # Ctrl+y + ,
  ];

  # Copy Applications to ~/Applications to allow them to be launched from Spotlight
  disabledModules = [ "targets/darwin/linkapps.nix" ];
  home.activation = lib.mkIf pkgs.stdenv.isDarwin {
    copyApplications =
      let
        apps = pkgs.buildEnv {
          name = "home-manager-applications";
          paths = config.home.packages;
          pathsToLink = "/Applications";
        };
      in
      lib.hm.dag.entryAfter [ "writeBoundary" ] ''
        baseDir="$HOME/Applications/Home Manager Apps"
        if [ -d "$baseDir" ]; then
          rm -rf "$baseDir"
        fi
        mkdir -p "$baseDir"
        for appFile in ${apps}/Applications/*; do
          target="$baseDir/$(basename "$appFile")"
          $DRY_RUN_CMD cp ''${VERBOSE_ARG:+-v} -fHRL "$appFile" "$baseDir"
          $DRY_RUN_CMD chmod ''${VERBOSE_ARG:+-v} -R +w "$target"
        done
      '';
  };

  home.stateVersion = "23.05";
}