nixos-config/hosts/worf/home.nix

{ pkgs
, lib
, inputs
, config
, ...
}: {
  imports = [
    ./neovim.nix
    ./zsh.nix
  ];

  home.packages = with pkgs; [
    bat
    bottom
    cocoapods
    emacs
    exa
    gnutar
    iterm2
    ncdu
    neofetch
    nix-index
    nodejs
    # unstable.ripes
    spotify
    tldr
    vscode
  ];

  programs.git = {
    enable = true;

    extraConfig = {
      pull.rebase = true;
      push.autoSetupRemote = true;
      color.ui = "auto";
      init.defaultBranch = "main";
      lfs.enable = true;

      user = {
        name = "Felix Albrigtsen";
        email = "felix@albrigtsen.it";
      };
    };
    ignores = [
      "*~"
      "*.swp"
      ".DS_Store"
      ".vscode"
    ];
  };

  programs.nix-index = {
    enable = true;
    enableZshIntegration = true;
  };

  # Copy Applications to ~/Applications to allow them to be launched from Spotlight
  disabledModules = [ "targets/darwin/linkapps.nix" ];
  home.activation = lib.mkIf pkgs.stdenv.isDarwin {
    copyApplications =
      let
        apps = pkgs.buildEnv {
          name = "home-manager-applications";
          paths = config.home.packages;
          pathsToLink = "/Applications";
        };
      in
      lib.hm.dag.entryAfter [ "writeBoundary" ] ''
        baseDir="$HOME/Applications/Home Manager Apps"
        if [ -d "$baseDir" ]; then
          rm -rf "$baseDir"
        fi
        mkdir -p "$baseDir"
        for appFile in ${apps}/Applications/*; do
          target="$baseDir/$(basename "$appFile")"
          $DRY_RUN_CMD cp ''${VERBOSE_ARG:+-v} -fHRL "$appFile" "$baseDir"
          $DRY_RUN_CMD chmod ''${VERBOSE_ARG:+-v} -R +w "$target"
        done
      '';
  };

  home.stateVersion = "23.05";
}