{
  description = "RCON -> Bluemap player position API converter";

  inputs.nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";

  outputs = { self, nixpkgs }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs { inherit system; };
      inherit (pkgs) lib;
    in {
      devShells.${system}.default = pkgs.mkShell.override { stdenv = pkgs.clangStdenv; } {
        packages = with pkgs; [
          clang-tools
          pkg-config
        ];

        buildInputs = with pkgs; [
          cmocka
        ];

        env = {
          CC = "clang";
          CXX = "clang++";
        };
      };

      packages.${system} = let
        src = lib.fileset.toSource {
          root = ./.;
          fileset = lib.fileset.unions [
            ./Makefile
            ./src
            ./test
          ];
        };
      in {
        default = self.packages.${system}.wamf;
        wamf = pkgs.callPackage ./nix/package.nix {
          inherit src;
          stdenv = pkgs.clangStdenv;
        };
        wamf-freebsd-cross = let
          pkgs = import nixpkgs {
            localSystem = system;
            crossSystem = "x86_64-freebsd";
          };
        in pkgs.callPackage ./nix/package.nix {
          inherit src;
          stdenv = pkgs.clangStdenv;
        };
        coverage-html =  pkgs.callPackage ./nix/coverage-html.nix {
          inherit src;
          stdenv = pkgs.clangStdenv;
        };
      };
    };
}