{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    rust-overlay.url = "github:oxalica/rust-overlay";
    rust-overlay.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = { self, nixpkgs, rust-overlay}:
  let
    inherit (nixpkgs) lib;

    systems = [
      "x86_64-linux"
      "aarch64-linux"
      "x86_64-darwin"
      "aarch64-darwin"
      "armv7l-linux"
    ];

    forAllSystems = f: nixpkgs.lib.genAttrs systems (system: let
      pkgs = import nixpkgs {
        inherit system;
        overlays = [
          (import rust-overlay)
        ];
      };

      rust-bin = rust-overlay.lib.mkRustBin { } pkgs.buildPackages;
      toolchain = rust-bin.nightly.latest.default.override {
        extensions = [ "rust-src" ];
      };
    in f system pkgs toolchain);
  in {
    devShell = forAllSystems (system: pkgs: toolchain: pkgs.mkShell {
      nativeBuildInputs = with pkgs; [
        toolchain
        cargo-edit
      ];

      env = {
        RUST_SRC_PATH = "${toolchain}/lib/rustlib/src/rust/library";
        RUSTFLAGS = "-Zhigher-ranked-assumptions";
      };
    });

    overlays = {
      default = self.overlays.donquota;
      donquota = final: prev: {
        inherit (self.packages.${prev.stdenv.hostPlatform.system}) donquota;
      };
    };

    packages = forAllSystems (system: pkgs: _:
      let
      cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
      cargoLock = ./Cargo.lock;
      src = lib.fileset.toSource {
        root = ./.;
        fileset = lib.fileset.unions [
          ./src
          ./Cargo.toml
          ./Cargo.lock
        ];
      };

      rustPlatform = pkgs.makeRustPlatform {
        rustc = pkgs.rust-bin.nightly.latest.default;
        cargo = pkgs.rust-bin.nightly.latest.cargo;
      };
    in {
      default = self.packages.${system}.donquota;

      donquota = pkgs.callPackage ./nix/package.nix { inherit cargoToml cargoLock src rustPlatform; };

      filteredSource = pkgs.runCommandLocal "filtered-source" { } ''
        ln -s ${src} $out
      '';
    });
  };
}