{ self, nixpkgs }:
nixpkgs.lib.nixosSystem {
  system = "x86_64-linux";
  pkgs = import nixpkgs {
    system = "x86_64-linux";
    overlays = [
      self.overlays.bro
    ];
  };
  modules = [
    "${nixpkgs}/nixos/modules/virtualisation/qemu-vm.nix"
    "${nixpkgs}/nixos/tests/common/user-account.nix"

    self.nixosModules.default

    ({ config, lib, pkgs, ... }: {
      system.stateVersion = config.system.nixos.release;
      virtualisation.graphics = false;

      services.getty.autologinUser = "alice";

      users = {
        users.alice.extraGroups = [
          "wheel"
          "systemd-journal"
        ];
        extraUsers.root.password = "root";
        motd = ''
          =================================
          Welcome to the bro vm!

          Password for alice is 'foobar'
          Password for root is 'root'

          To exit, press Ctrl+A, then X
          =================================
        '';
      };

      services.bro = {
        enable = true;

        instances.ls = {
          enable = true;

          client = {
            settings.BRO_FILE_ARGS = true;
          };

          server = {
            settings = {
              executable = lib.getExe' pkgs.coreutils "ls";
              allowed-env = [ "LS_COLORS" "TIME_STYLE" "QUOTING_STYLE" ];
            };
          };
        };
      };

      environment.systemPackages = [
        config.services.bro.instances.ls.client.package
      ];

      programs.vim = {
        enable = true;
        defaultEditor = true;
      };
    })
  ];
}